Réécrire un Code VB en Windev

Cette section est consacrée aux développements d'applications interfacées avec les logiciels Sage.

Modérateurs: Super-Apogea, Super Modérateur

Réécrire un Code VB en Windev

de Sageokan » Jeu 29 Oct 2020 16:04

Bonjour ,
J'ai ce code ci-dessous
Code: Tout sélectionner
Option Strict Off
Imports Objets100cLib
Imports System
 
Module ModEncoder
    'Objet base comptable
    Dim oCpta As BSCPTAApplication100c
    'emplacement du fichier comptable
    Dim sPathMae As String = "C:\temp\Bijou.mae"
 
    Sub Main()
        Try
            'Instanciation de l'objet base comptable
            oCpta = New BSCPTAApplication100c
            'Ouverture de la base
            If OpenBase(oCpta, sPathMae) Then
                'Création d'un objet processus Saisie de pièce comptable
                Dim mProcessEncoder As IPMEncoder = oCpta.CreateProcess_Encoder
                'Génération de la pièce
                ReglementFacture(mProcessEncoder)
                'Si les écritures du processus ne sont pas correctes
                If Not mProcessEncoder.CanProcess Then
                    'Récupération des erreurs 
                    RecupError(mProcessEncoder)
                Else
                    'Gérération de la pièce dans la base
    mProcessEncoder.Process()
                End If
            End If
        Catch ex As Exception
            Console.WriteLine("Erreur : " & ex.Message)
        End Try
        CloseBase(oCpta)
    End Sub
 
    Public Sub ReglementFacture(ByRef mP As IPMEncoder)
        Dim mEcTiers, mEcCompte As IBOEcriture3
        Dim dMnt As Double = 10000
        Try
            'Affectation des propriétés globales 
            'Journal
            mP.Journal = oCpta.FactoryJournal.ReadNumero("BEU")
            'Date
            mP.Date = #3/22/2009#
            'Numéro de pièce
            mP.EC_Piece = mP.Journal.NextEC_Piece(#3/22/2009#)
            'Intitulé
            mP.EC_Intitule = "Reglement Facture"
 
            'Création de l'écriture tiers
            mEcTiers = mP.FactoryEcritureIn.Create
            'Affectation compte général
            mEcTiers.CompteG = oCpta.FactoryCompteG.ReadNumero("4010000")
            'Affectation compte tiers
            mEcTiers.Tiers = oCpta.FactoryTiers.ReadNumero("HOLDI")
            'Affectation sens de l'écriture
            mEcTiers.EC_Sens = EcritureSensType.EcritureSensTypeDebit
            'Affectation du montant
            mEcTiers.EC_Montant = dMnt
            'Ajout de l'écriture au processus (écriture mémoire non persistante)
            mEcTiers.WriteDefault()
  'Création de l'écriture générale
            mEcCompte = mP.FactoryEcritureIn.Create
            'Affectation compte général
            mEcCompte.CompteG = oCpta.FactoryCompteG.ReadNumero("5120")
            'Affectation sens de l'écriture
            mEcCompte.EC_Sens = EcritureSensType.EcritureSensTypeCredit
            'Affectation du montant
            mEcCompte.EC_Montant = dMnt
            'Ajout de l'écriture au processus (écriture mémoire non persistante)
            mEcCompte.WriteDefault()
        Catch ex As Exception
            Console.WriteLine("Erreur : " & ex.Message)
        End Try
    End Sub
 
    Public Sub RecupError(ByRef mP As IPMEncoder)
        Try
            'Boucle sur les erreurs contenues dans la collection
            For i As Integer = 1 To mP.Errors.Count
                'Récupération des éléments erreurs 
                Dim iFail As IFailInfo = mP.Errors.Item(i)
                'récupération du numéro d'erreur, de l'indice et de la description de l'erreur
                Console.WriteLine("Code Erreur : " & iFail.ErrorCode & " Indice : " & iFail.Indice & _
                " Description : " & iFail.Text)
            Next
        Catch ex As Exception
            Console.WriteLine("Erreur : " & ex.Message)
        End Try
    End Sub
 
    Public Function OpenBase(ByRef BaseCpta As BSCPTAApplication100c, ByVal sMae As String, _
    Optional ByVal sUid As String = "<Administrateur>", _
        Optional ByVal sPwd As String = "") As Boolean
        Try
            'Affectation de l'emplacement du fichier comptable
            BaseCpta.Name = sMae
  'Affectation du code utilisateur
            BaseCpta.Loggable.UserName = sUid
            'Affectation du mot de passe
            BaseCpta.Loggable.UserPwd = sPwd
            'Ouverture de la base comptable
            BaseCpta.Open()
            Return True
        Catch ex As Exception
            Console.WriteLine("Erreur lors de l'ouverture du fichier mae : " & ex.Message)
            Return False
        End Try
    End Function
 
    Private Function CloseBase(ByRef BaseCpta As BSCPTAApplication100c) As Boolean
        Try
            'Si la base est ouverte, alors fermeture de la base
            If BaseCpta.IsOpen Then BaseCpta.Close()
            Return True
        Catch ex As Exception
            Console.WriteLine("Erreur lors de la fermeture de la base : " & ex.Message)
            Return False
        End Try
    End Function
End Module



Quelqu'un peut-il me le mettre en Windev que je comprenne ?
Merci
Posteur néophyte
Posteur néophyte
 
Messages: 14
Inscription: Mar 18 Déc 2018 21:10

Qui est en ligne
Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 2 invités